home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Apple II Magazines (DO)
/
Softdisk Magazette Volume 2, No. 07 (1983-03)(Softdisk)(Side B).zip
/
Softdisk Magazette Volume 2, No. 07 (1983-03)(Softdisk)(Side B).do
/
COLOR SLOT.int
< prev
next >
Wrap
Text File
|
1996-12-24
|
5KB
|
142 lines
10 REM ***COLOR SLOT***
20 REM WRITTEN 1978 BY P.R. ZACHEIS
30 DIM A$(4),C$(255),D$(255):AA=0
40 POKE 2,173: POKE 3,48: POKE 4,192: POKE 5,165: POKE 6,0: POKE 7,32: POKE 8,168: POKE 9,252: POKE 10,165: POKE 11,1: POKE 12,208: POKE 13,4
50 POKE 14,198: POKE 15,24: POKE 16,240: POKE 17,5: POKE 18,198: POKE 19,1: POKE 20,76: POKE 21,2: POKE 22,0: POKE 23,96
60 TEXT :CALL (-936):VTAB 2:TAB 13:PRINT "***": POKE 50,127:VTAB 2:TAB 16
70 PRINT "COLOR": POKE 50,255:VTAB 2:TAB 22: POKE 50,127:PRINT "SLOT": POKE 50,255:VTAB 2:TAB 26:PRINT "***"
80 TAB 20:PRINT "BY"
90 TAB 14:PRINT "PAUL R ZACHEIS"
100 FOR R=1 TO 100:GOSUB 1370:NEXT R
110 VTAB 6:PRINT " YOU HAVE JUST ENTERED THE WORLD OF":TAB 19:PRINT "THE":TAB 13:PRINT "ONE-ARMED BANDIT"
120 PRINT :PRINT " YOU HAVE $500 (GIFT OF A RICH UNCLE)"
130 PRINT :PRINT " TO PLAY COLOR SLOT SELECT 1,2 OR 3:"
140 TAB 12:PRINT "1-BET ANY AMOUNT FROM":TAB 18:PRINT "$1 TO $100":TAB 15:PRINT "TYPE IN AMOUNT AND RETURN"
150 TAB 12:PRINT "2-BET A CONSTANT AMOUNT.":TAB 18:PRINT "PRESS RETURN"
160 TAB 12:PRINT "3-AUTOMATIC PLAY"
170 PRINT
180 INPUT " WHICH WOULD YOU LIKE? 1,2 OR 3",AA:IF AA=1 THEN 210
190 IF AA=2 OR AA=3 THEN INPUT " WHAT CONSTANT BET WOULD YOU LIKE FROM $1 TO $100",B:IF B<1 THEN 190:IF B>100 THEN 190
200 CALL -936:VTAB 10:
210 TAB 4:PRINT "WOULD YOU LIKE TO SEE PAY-OFF ODDS?"
220 TAB 18:INPUT "(Y/N)",A$
230 IF A$(1)#"Y" THEN 310:CALL (-936)
240 VTAB 3:TAB 12:PRINT "***PAY-OFF TABLE***":PRINT :TAB 7:PRINT "FOR":VTAB 5:TAB 33:PRINT "ODDS"
250 PRINT :TAB 8:PRINT "ALL THREE BLUE-----------50 TO 1"
260 PRINT :TAB 8:PRINT "THREE SAME COLOR---------15 TO 1":PRINT
270 TAB 8:PRINT "1ST TWO SAME COLOR-------3 TO 1":PRINT
280 TAB 8:PRINT "LAST TWO SAME COLOR------2 TO 1":
290 PRINT :TAB 9:PRINT "REMEMBER YOUR BANK IS $500"
300 PRINT :PRINT :INPUT "PRESS RETURN WHEN READY",E$
310 GR :CALL (-936)
320 COLOR= 15:VLIN 2,36 AT 13:VLIN 2,36 AT 26:
330 K=500
340 PRINT "YOUR BANKROLL IS=$";K
350 IF K>=10000 THEN 800
360 IF AA=1 THEN 390
370 IF AA=2 THEN 400
380 IF AA=3 THEN 410
390 INPUT "YOUR BET IS $",B:GOTO 420
400 INPUT "PRESS RETURN",E$
410 PRINT "YOUR BET IS $";B
420 IF B<1 THEN PRINT "BET IS UNDER $1":IF B<1 THEN 340
430 IF B>100 THEN PRINT "BET IS OVER $100":IF B>100 THEN 340
440 IF B>K THEN B=K
450 GOSUB 890
460 J= RND (7)+7
470 COLOR= J:GOSUB 990:GOSUB 1020
480 GOSUB 930
490 C= RND (7)+7
500 COLOR= C:GOSUB 1060
510 GOSUB 960
520 D= RND (7)+7
530 COLOR= D:GOSUB 1090
540 IF J=7 AND C=7 AND D=7 THEN 660
550 IF J=C AND C=D THEN 620
560 IF J=C THEN 700
570 IF C=D THEN 740
580 PRINT "YOU LOSE"
590 K=K-B
600 IF K<=0 THEN 780
610 GOTO 830
620 POKE 50,127:TAB 17:PRINT "JACKPOT": POKE 50,255
630 GOSUB 1160
640 PRINT "YOU WIN $";B*15
650 K=K+B*15:GOTO 830
660 TAB 10: POKE 50,127:PRINT "SUPER JACKPOT": POKE 50,255
670 FOR R=1 TO 100:GOSUB 1370:NEXT R
680 PRINT "YOU WIN $";B*50:
690 K=K+B*50:GOTO 830
700 POKE 50,127:TAB 17:PRINT "WINNER": POKE 50,255
710 GOSUB 1130
720 PRINT "YOU WIN $";B*3
730 K=K+B*3:GOTO 830
740 POKE 50,127:TAB 17:PRINT "WINNER": POKE 50,255
750 GOSUB 1130
760 PRINT "YOU WIN $";B*2
770 K=K+B*2:GOTO 830
780 GOSUB 1160
790 TEXT :CALL -936:VTAB 5:TAB 10:PRINT "YOU LOST YOUR ROLL":GOSUB 1190:TAB 15:VTAB 20:PRINT "THANK YOU, COME AGAIN":END
800 GOSUB 1330:TEXT :CALL -936:TAB 10:VTAB 10: POKE 50,127:PRINT "YOU BROKE THE BANK": POKE 50,255
810 GOSUB 1250
820 FOR M=1 TO 300:NEXT M:GR :GOSUB 1330:TEXT :CALL -936:VTAB 10:PRINT "PLEASE GO TO ANOTHER CASINO":TAB 10:VTAB 17:PRINT "THANK YOU":END
830 COLOR= 0
840 FOR V=1 TO 300:NEXT V
850 GOSUB 1020
860 GOSUB 1060
870 GOSUB 1090
880 GOTO 340
890 FOR X=1 TO 14
900 COLOR= X:GOSUB 990:GOSUB 1020:NEXT X
910 RETURN
920 END
930 FOR Y=1 TO 14
940 COLOR= Y:GOSUB 990:GOSUB 1060:NEXT Y
950 RETURN
960 FOR R=1 TO 14
970 COLOR= R:GOSUB 990:GOSUB 1090:NEXT R
980 RETURN
990 FOR T=1 TO 250
1000 T= PEEK (-16336)+ PEEK (-16336)
1010 NEXT T:RETURN
1020 FOR Z=3 TO 10
1030 VLIN 16,23 AT Z:NEXT Z
1040 HLIN 5,8 AT 15:HLIN 2,11 AT 23:HLIN 6,7 AT 24:
1050 GOSUB 990:RETURN
1060 FOR P=16 TO 23:VLIN 16,23 AT P:NEXT P
1070 HLIN 18,21 AT 15:HLIN 15,24 AT 23:HLIN 19,20 AT 24
1080 GOSUB 990:RETURN
1090 FOR L=29 TO 36
1100 VLIN 16,23 AT L:NEXT L
1110 HLIN 31,34 AT 15:HLIN 28,37 AT 23:HLIN 32,33 AT 24
1120 GOSUB 990:RETURN
1130 FOR S=1 TO 100
1140 M= PEEK (-16336)- PEEK (-16336)+ PEEK (-16336)- PEEK (-16336)+ PEEK (-16336)- PEEK (-16336)
1150 NEXT S:RETURN
1160 FOR F=1 TO 500
1170 M= PEEK (-16336)- PEEK (-16336)+ PEEK (-16336)
1180 NEXT F:RETURN
1190 D$="6201620152116201521162020084"
1200 FOR Z=1 TO LEN(D$)-3 STEP 4
1210 Z1=( ASC(D$(Z))-176)*( ASC(D$(Z+1))-176)+ ASC(D$(Z+2))-176
1220 Z2=40-Z1: POKE 0,Z2: POKE 24, ASC(D$(Z+3))-176
1230 POKE 1,150
1240 CALL 2:NEXT Z:RETURN
1250 C$="0011005100510081008125312533"
1260 C$(29)="197219722531253200810081"
1270 C$(53)="00510052"
1280 FOR Z=1 TO LEN(C$)-3 STEP 4
1290 Z1=( ASC(C$(Z))-176)*( ASC(C$(Z+1))-176)+ ASC(C$(Z+2))-176
1300 Z2=40-Z1: POKE 0,Z2: POKE 24, ASC(C$(Z+3))-176
1310 POKE 1,75
1320 CALL 2:NEXT Z:RETURN
1330 FOR Q=1 TO 3:
1340 COLOR= RND (16):FOR I=18 TO 0 STEP -2:J=39-I:VLIN I+2,J AT I+2:GOSUB 1370:HLIN I+2,J AT J:GOSUB 1370:
1350 VLIN I,J AT J:GOSUB 1370:HLIN I,J AT I:GOSUB 1370:NEXT I,Q
1360 RETURN
1370 H= RND (30)+3:T=H*H*5+H*26+70:V=32767/T
1380 POKE 0,H
1390 POKE 1,V MOD 256
1400 POKE 24,(V>255)+1
1410 CALL 2:RETURN