home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (DO) / Softdisk Magazette Volume 2, No. 07 (1983-03)(Softdisk)(Side B).zip / Softdisk Magazette Volume 2, No. 07 (1983-03)(Softdisk)(Side B).do / COLOR SLOT.int < prev    next >
Text File  |  1996-12-24  |  5KB  |  142 lines
  1. 10 REM ***COLOR SLOT***
  2. 20 REM  WRITTEN 1978 BY P.R. ZACHEIS
  3. 30 DIM A$(4),C$(255),D$(255):AA=0
  4. 40  POKE 2,173: POKE 3,48: POKE 4,192: POKE 5,165: POKE 6,0: POKE 7,32: POKE 8,168: POKE 9,252: POKE 10,165: POKE 11,1: POKE 12,208: POKE 13,4
  5. 50  POKE 14,198: POKE 15,24: POKE 16,240: POKE 17,5: POKE 18,198: POKE 19,1: POKE 20,76: POKE 21,2: POKE 22,0: POKE 23,96
  6. 60 TEXT :CALL (-936):VTAB 2:TAB 13:PRINT "***": POKE 50,127:VTAB 2:TAB 16
  7. 70 PRINT "COLOR": POKE 50,255:VTAB 2:TAB 22: POKE 50,127:PRINT "SLOT": POKE 50,255:VTAB 2:TAB 26:PRINT "***"
  8. 80 TAB 20:PRINT "BY"
  9. 90 TAB 14:PRINT "PAUL R ZACHEIS"
  10. 100 FOR R=1 TO 100:GOSUB 1370:NEXT R
  11. 110 VTAB 6:PRINT "   YOU HAVE JUST ENTERED THE WORLD OF":TAB 19:PRINT "THE":TAB 13:PRINT "ONE-ARMED BANDIT"
  12. 120 PRINT :PRINT "   YOU HAVE $500 (GIFT OF A RICH UNCLE)"
  13. 130 PRINT :PRINT "     TO PLAY COLOR SLOT SELECT 1,2 OR 3:"
  14. 140 TAB 12:PRINT "1-BET ANY AMOUNT FROM":TAB 18:PRINT "$1 TO $100":TAB 15:PRINT "TYPE IN AMOUNT AND RETURN"
  15. 150 TAB 12:PRINT "2-BET A CONSTANT AMOUNT.":TAB 18:PRINT "PRESS RETURN"
  16. 160 TAB 12:PRINT "3-AUTOMATIC PLAY"
  17. 170 PRINT 
  18. 180 INPUT "    WHICH WOULD YOU LIKE? 1,2 OR 3",AA:IF AA=1 THEN 210
  19. 190 IF AA=2 OR AA=3 THEN INPUT "    WHAT CONSTANT BET WOULD YOU LIKE                FROM $1 TO $100",B:IF B<1 THEN 190:IF B>100 THEN 190
  20. 200 CALL -936:VTAB 10:
  21. 210 TAB 4:PRINT "WOULD YOU LIKE TO SEE PAY-OFF ODDS?"
  22. 220 TAB 18:INPUT "(Y/N)",A$
  23. 230 IF A$(1)#"Y" THEN 310:CALL (-936)
  24. 240 VTAB 3:TAB 12:PRINT "***PAY-OFF TABLE***":PRINT :TAB 7:PRINT "FOR":VTAB 5:TAB 33:PRINT "ODDS"
  25. 250 PRINT :TAB 8:PRINT "ALL THREE BLUE-----------50 TO 1"
  26. 260 PRINT :TAB 8:PRINT "THREE SAME COLOR---------15 TO 1":PRINT 
  27. 270 TAB 8:PRINT "1ST TWO SAME COLOR-------3 TO 1":PRINT 
  28. 280 TAB 8:PRINT "LAST TWO SAME COLOR------2 TO 1":
  29. 290 PRINT :TAB 9:PRINT "REMEMBER YOUR BANK IS $500"
  30. 300 PRINT :PRINT :INPUT "PRESS RETURN WHEN READY",E$
  31. 310 GR :CALL (-936)
  32. 320 COLOR= 15:VLIN 2,36 AT 13:VLIN 2,36 AT 26:
  33. 330 K=500
  34. 340 PRINT "YOUR BANKROLL IS=$";K
  35. 350 IF K>=10000 THEN 800
  36. 360 IF AA=1 THEN 390
  37. 370 IF AA=2 THEN 400
  38. 380 IF AA=3 THEN 410
  39. 390 INPUT "YOUR BET IS $",B:GOTO 420
  40. 400 INPUT "PRESS RETURN",E$
  41. 410 PRINT "YOUR BET IS $";B
  42. 420 IF B<1 THEN PRINT "BET IS UNDER $1":IF B<1 THEN 340
  43. 430 IF B>100 THEN PRINT "BET IS OVER $100":IF B>100 THEN 340
  44. 440 IF B>K THEN B=K
  45. 450 GOSUB 890
  46. 460 J= RND (7)+7
  47. 470 COLOR= J:GOSUB 990:GOSUB 1020
  48. 480 GOSUB 930
  49. 490 C= RND (7)+7
  50. 500 COLOR= C:GOSUB 1060
  51. 510 GOSUB 960
  52. 520 D= RND (7)+7
  53. 530 COLOR= D:GOSUB 1090
  54. 540 IF J=7 AND C=7 AND D=7 THEN 660
  55. 550 IF J=C AND C=D THEN 620
  56. 560 IF J=C THEN 700
  57. 570 IF C=D THEN 740
  58. 580 PRINT "YOU LOSE"
  59. 590 K=K-B
  60. 600 IF K<=0 THEN 780
  61. 610 GOTO 830
  62. 620  POKE 50,127:TAB 17:PRINT "JACKPOT": POKE 50,255
  63. 630 GOSUB 1160
  64. 640 PRINT "YOU WIN $";B*15
  65. 650 K=K+B*15:GOTO 830
  66. 660 TAB 10: POKE 50,127:PRINT "SUPER JACKPOT": POKE 50,255
  67. 670 FOR R=1 TO 100:GOSUB 1370:NEXT R
  68. 680 PRINT "YOU WIN $";B*50:
  69. 690 K=K+B*50:GOTO 830
  70. 700  POKE 50,127:TAB 17:PRINT "WINNER": POKE 50,255
  71. 710 GOSUB 1130
  72. 720 PRINT "YOU WIN $";B*3
  73. 730 K=K+B*3:GOTO 830
  74. 740  POKE 50,127:TAB 17:PRINT "WINNER": POKE 50,255
  75. 750 GOSUB 1130
  76. 760 PRINT "YOU WIN $";B*2
  77. 770 K=K+B*2:GOTO 830
  78. 780 GOSUB 1160
  79. 790 TEXT :CALL -936:VTAB 5:TAB 10:PRINT "YOU LOST YOUR ROLL":GOSUB 1190:TAB 15:VTAB 20:PRINT "THANK YOU, COME AGAIN":END 
  80. 800 GOSUB 1330:TEXT :CALL -936:TAB 10:VTAB 10: POKE 50,127:PRINT "YOU BROKE THE BANK": POKE 50,255
  81. 810 GOSUB 1250
  82. 820 FOR M=1 TO 300:NEXT M:GR :GOSUB 1330:TEXT :CALL -936:VTAB 10:PRINT "PLEASE GO TO ANOTHER CASINO":TAB 10:VTAB 17:PRINT "THANK YOU":END 
  83. 830 COLOR= 0
  84. 840 FOR V=1 TO 300:NEXT V
  85. 850 GOSUB 1020
  86. 860 GOSUB 1060
  87. 870 GOSUB 1090
  88. 880 GOTO 340
  89. 890 FOR X=1 TO 14
  90. 900 COLOR= X:GOSUB 990:GOSUB 1020:NEXT X
  91. 910 RETURN 
  92. 920 END 
  93. 930 FOR Y=1 TO 14
  94. 940 COLOR= Y:GOSUB 990:GOSUB 1060:NEXT Y
  95. 950 RETURN 
  96. 960 FOR R=1 TO 14
  97. 970 COLOR= R:GOSUB 990:GOSUB 1090:NEXT R
  98. 980 RETURN 
  99. 990 FOR T=1 TO 250
  100. 1000 T= PEEK (-16336)+ PEEK (-16336)
  101. 1010 NEXT T:RETURN 
  102. 1020 FOR Z=3 TO 10
  103. 1030 VLIN 16,23 AT Z:NEXT Z
  104. 1040 HLIN 5,8 AT 15:HLIN 2,11 AT 23:HLIN 6,7 AT 24:
  105. 1050 GOSUB 990:RETURN 
  106. 1060 FOR P=16 TO 23:VLIN 16,23 AT P:NEXT P
  107. 1070 HLIN 18,21 AT 15:HLIN 15,24 AT 23:HLIN 19,20 AT 24
  108. 1080 GOSUB 990:RETURN 
  109. 1090 FOR L=29 TO 36
  110. 1100 VLIN 16,23 AT L:NEXT L
  111. 1110 HLIN 31,34 AT 15:HLIN 28,37 AT 23:HLIN 32,33 AT 24
  112. 1120 GOSUB 990:RETURN 
  113. 1130 FOR S=1 TO 100
  114. 1140 M= PEEK (-16336)- PEEK (-16336)+ PEEK (-16336)- PEEK (-16336)+ PEEK (-16336)- PEEK (-16336)
  115. 1150 NEXT S:RETURN 
  116. 1160 FOR F=1 TO 500
  117. 1170 M= PEEK (-16336)- PEEK (-16336)+ PEEK (-16336)
  118. 1180 NEXT F:RETURN 
  119. 1190 D$="6201620152116201521162020084"
  120. 1200 FOR Z=1 TO  LEN(D$)-3 STEP 4
  121. 1210 Z1=( ASC(D$(Z))-176)*( ASC(D$(Z+1))-176)+ ASC(D$(Z+2))-176
  122. 1220 Z2=40-Z1: POKE 0,Z2: POKE 24, ASC(D$(Z+3))-176
  123. 1230  POKE 1,150
  124. 1240 CALL 2:NEXT Z:RETURN 
  125. 1250 C$="0011005100510081008125312533"
  126. 1260 C$(29)="197219722531253200810081"
  127. 1270 C$(53)="00510052"
  128. 1280 FOR Z=1 TO  LEN(C$)-3 STEP 4
  129. 1290 Z1=( ASC(C$(Z))-176)*( ASC(C$(Z+1))-176)+ ASC(C$(Z+2))-176
  130. 1300 Z2=40-Z1: POKE 0,Z2: POKE 24, ASC(C$(Z+3))-176
  131. 1310  POKE 1,75
  132. 1320 CALL 2:NEXT Z:RETURN 
  133. 1330 FOR Q=1 TO 3:
  134. 1340 COLOR=  RND (16):FOR I=18 TO 0 STEP -2:J=39-I:VLIN I+2,J AT I+2:GOSUB 1370:HLIN I+2,J AT J:GOSUB 1370:
  135. 1350 VLIN I,J AT J:GOSUB 1370:HLIN I,J AT I:GOSUB 1370:NEXT I,Q
  136. 1360 RETURN 
  137. 1370 H= RND (30)+3:T=H*H*5+H*26+70:V=32767/T
  138. 1380  POKE 0,H
  139. 1390  POKE 1,V MOD 256
  140. 1400  POKE 24,(V>255)+1
  141. 1410 CALL 2:RETURN 
  142.